PE에서 Edge 끌어 오기

@echo off
mode con cols=70 lines=11
if "%SystemDrive%" NEQ "X:" exit
setlocal enabledelayedexpansion

for %%b in (C D E F G H I J K L M N O P Q R S T U V W Y) do (
if exist "%%b:\Program Files (x86)\Microsoft\Edge\Application" (set drv=%%b& goto main))
echo.&echo.&echo.&echo.
echo           윈도우 드라이브에 Edge 폴더가 없습니다.
choice /t 2 /d n >nul
exit

:main
echo.&echo.&echo.
Shortcut.exe /f:"X:\Users\Public\Desktop\저쪽 동네 Edge.lnk" /a:c /t:"%drv%:\Program Files (x86)\Microsoft\Edge\Application\msedge.exe" >nul
Shortcut.exe /f:"X:\Users\Public\Desktop\저쪽 동네 Edge.lnk" /a:e /P:"--user-data-dir=\"%userprofile%\AppData\Local\Microsoft\Edge\User Data\" --disable-gpu --allow-run-as-system --no-first-run --force-local-ntp --test-type --ignore-certificate-errors --no-sandbox https://www.naver.com/" >nul 
reg add "HKLM\SOFTWARE\Policies\Microsoft\Edge" /v "UserDataDir" /t REG_SZ /d "\"%userprofile%\AppData\Local\Microsoft\Edge\User Data\"" /f >nul

if /i        "%systemdrive%"=="%drv%:" set load=Software
if /i not "%systemdrive%"=="%drv%:" set load=load& reg load HKLM\Hive2 "%drv%:\Windows\System32\Config\Software" 1>nul 2>nul

:: 레지스트리 값 추출
for /f "tokens=2,*" %%a in ('reg query "HKEY_LOCAL_MACHINE\Hive2\Microsoft\Windows NT\CurrentVersion\Winlogon" /v DefaultUserName 2^>nul ^| findstr /C:"DefaultUserName"') do (
    set "DefaultUserName=%%b"
)
echo.&echo.
:: 값이 비어있는지 확인
if not "%DefaultUserName%"=="" (
    echo.                  계정 이름:%DefaultUserName%


    ) else (
    echo. DefaultUserName 값을 찾을 수 없습니다.
    )

set EUD=AppData\Local\Microsoft\Edge\User Data
xcopy /hryif "%drv%:\Users\%DefaultUserName%\%EUD%\First Run"  "X:\Users\Default\%EUD%\" >nul 
xcopy /hryif "%drv%:\Users\%DefaultUserName%\%EUD%\Last Browser"  "X:\Users\Default\%EUD%\" >nul
xcopy /hryif "%drv%:\Users\%DefaultUserName%\%EUD%\Last Version"  "X:\Users\Default\%EUD%\" >nul
xcopy /hryif "%drv%:\Users\%DefaultUserName%\%EUD%\Local State"  "X:\Users\Default\%EUD%\" >nul
xcopy /hryif "%drv%:\Users\%DefaultUserName%\%EUD%\Default\Bookmarks"  "X:\Users\Default\%EUD%\Default\"  >nul 
xcopy /hryif "%drv%:\Users\%DefaultUserName%\%EUD%\Default\Favicons"  "X:\Users\Default\%EUD%\Default\"  >nul 
xcopy /hryif "%drv%:\Users\%DefaultUserName%\%EUD%\Default\Preferences"  "X:\Users\Default\%EUD%\Default\"  >nul
xcopy /hryif "%drv%:\Users\%DefaultUserName%\%EUD%\Default\Secure Preferences"  "X:\Users\Default\%EUD%\Default\" >nul
xcopy /hryif "%drv%:\Users\%DefaultUserName%\%EUD%\Default\Edge Profile.ico"  "X:\Users\Default\%EUD%\Default\"  >nul
 if /i not "%systemdrive%"=="%drv%:" reg unload HKLM\Hive2 1>nul 2>nul
start X:\Users\Public\Desktop\"저쪽 동네 Edge.lnk"
choice /t 1 /d n >nul
exit